Centar za edukaciju-BiH


Stranice (1):1

#1 27.06.2015 18:33
Gjoreski Van mreze
Administrator
Registrovan od:02.02.2009
Postovi:1,828


Predmet:Send Maill
Ima nekoj ideja kako od vb6 program da isparam mail?
↑  ↓

#2 15.09.2015 13:39
Avko Van mreze
Administrator
Registrovan od:28.05.2014
Postovi:4,696


Predmet:Re: Send Maill
dragi prijatelju!
i ja sam se namucio sa time no nakon godina mukotrpnog istrazivanja uspio sam poslati mail iz VB6.
Na internetu ima jako puno primjera i svi su u srži isti i rade na istom principu, a razlikuju se u dizajnu koda.
Primjer1. Ovo radi kod mene 100%
Ovo je jedan jednostavni kod

PreuzmiIzvorni kôd (Visual Basic):
  1. Private Sub Command1_Click()
  2.     Call SendGMail
  3. End Sub
  4.  
  5.  
  6. Sub SendGMail()
  7.  
  8. ' Object creation
  9. Set objMsg = CreateObject("CDO.Message")
  10. Set msgConf = CreateObject("CDO.Configuration")
  11.  
  12. ' Server Configuration
  13. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
  14. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"
  15. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465
  16. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
  17. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "tvoj.mail@gmail.com"
  18. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "lozinka"
  19. msgConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1
  20. msgConf.Fields.Update
  21.  
  22. ' Email
  23. objMsg.To = "kome.saljes@gmail.com"
  24. objMsg.From = "tvoj.mail@gmail.com"
  25. objMsg.Subject = "naslov u poruci"
  26. objMsg.HTMLBody = "tekst poruke"
  27. objMsg.Sender = "Mr. Name"
  28.  
  29. Set objMsg.Configuration = msgConf
  30.  
  31. ' Send
  32. objMsg.Send
  33.  
  34. ' Clear
  35. Set objMsg = Nothing
  36. Set msgConf = Nothing
  37.  
  38. End Sub

Netko koristi umjesto procedure sendGMail,
funkciju sendGMail( "kome.saljes@gmail.com","tvoj.mail@gmail.com", "naslov u poruci","tekst poruke","Mr. Name")

primjer2. evo isti taj primjer (isto govno drugo pakovanje)
PreuzmiIzvorni kôd (Visual Basic):
  1. Private Sub SendEmail(strEmail, strEpass, strSendTo, strSubject, strTextBody , Optional strAttachment As String)
  2.   Dim objCDOMsg As New CDO.Message
  3.   Dim objCDOCon As New CDO.Configuration
  4.   Dim strSchemas As String
  5.  
  6.   strSchemas = "http://schemas.microsoft.com/cdo/configuration/"
  7.  
  8.   With objCDOCon.Fields
  9.     .Item(strSchemas & "sendusing") = 2
  10.     .Item(strSchemas & "smtpserver") = "smtp.gmail.com"
  11.     .Item(strSchemas & "smtpserverport") = 465
  12.     .Item(strSchemas & "smtpauthenticate") = 1
  13.     .Item(strSchemas & "sendusername") = strEmail  ' Your gmail
  14.    .Item(strSchemas & "sendpassword") = strEpass ' Your password
  15.    .Item(strSchemas & "smtpconnectiontimeout") = 30
  16.     .Item(strSchemas & "smtpusessl") = 1
  17.     .Update
  18.   End With
  19.  
  20.   ' Construct your email
  21.  With objCDOMsg
  22.     .From = strEmail                 ' Your Email
  23.    .To = strSendTo                 ' Send to any email (example: example@yahoo.com)
  24.    .Subject = strSubject         ' Subject
  25.    .TextBody = strTextBody   '  Body
  26.    .Sender = strEmail             ' Your Email
  27.    .ReplyTo = strEmail            ' Your Email
  28.    .AddAttachment strAttachment  ' Your Attachment
  29.    Set .Configuration = objCDOCon
  30.     .Send                                 ' Send Email
  31.  End With
  32. End Sub

VAZNO:
Da bi ti ovo radilo moras napraviti dvije(2) stvari:
1. u Project-Reference ukljuciti Microsoft CDO for windows 2000 library
2. moras u gmailu na sigurnosti uklkjuciti na ON inace ti nece raditi kao ni meni.

nakon sto posjetis ovaj link https://www.google.com/...secureapps
ispisati ce ti se tekst :
Some apps and devices use less secure sign-in technology, which makes your account more vulnerable. You can turn off access for these apps, which we recommend, or turn on access if you want to use them despite the risks.

a onda izaberes ON i dozvolices svojoj "sumnjivoj" aplikaciji da pristupi tvome racunu i uz pomoc smtp.gmail.com protokola posalje mail nekoj drugoj osobi

nadam se da sam ti pomogao, stavio sam i program da nemoras prepisivati.
vidis kako sam dobar, aaa? sta kaze?
jesam li zasluzio pseći kolačić?
mmmm, av-av

Prilozi:
Informacije o tipu datoteke za:rar  sendGmail.rar
Preuzimanja:388
Velicina datoteke:1.56 KB


zivot je moja domovina.
↑  ↓

#3 15.09.2015 15:14
Gjoreski Van mreze
Administrator
Registrovan od:02.02.2009
Postovi:1,828


Predmet:Re: Send Maill
Fala kolega ,go resiv ova samo zaboravov da napisam odgovor.
Reseno slicno kako tvojot prv primer.
Vo sekoj slucaj Fala mnogu.
↑  ↓

Stranice (1):1


Sva vremena su GMT +01:00. Trenutno vrijeme: 9: 32 am.